SPICEメモ

.SUBCKT DFCSN1 Q QN   CDN CP D SDN 
M1      U14_U7_DRAIN CDN     VSS     VSS     N   L=.35U  W=1.80U  
M2      MFB     IND     U14_U7_DRAIN VSS     N   L=.35U  W=1.80U  
M3      MFB     IND     VDD     VDD     P   L=.35U  W=2.25U  
M4      MFB     CDN     VDD     VDD     P   L=.35U  W=2.25U  
M5      U15_U7_DRAIN SDN     VSS     VSS     N   L=.35U  W=3.00U  
M6      O2      O1      U15_U7_DRAIN VSS     N   L=.35U  W=3.00U  
M7      O2      O1      VDD     VDD     P   L=.35U  W=3.75U  
M8      O2      SDN     VDD     VDD     P   L=.35U  W=3.75U  
M9      U13_U7_DRAIN SDN     VSS     VSS     N   L=.35U  W=3.00U  
M10     IND     U7_S    U13_U7_DRAIN VSS     N   L=.35U  W=3.00U  
M11     IND     U7_S    VDD     VDD     P   L=.35U  W=3.75U  
M12     IND     SDN     VDD     VDD     P   L=.35U  W=3.75U  
M13     U12_U7_DRAIN CDN     VSS     VSS     N   L=.35U  W=3.00U  
M14     O1      U9_S    U12_U7_DRAIN VSS     N   L=.35U  W=3.00U  
M15     O1      U9_S    VDD     VDD     P   L=.35U  W=3.75U  
M16     O1      CDN     VDD     VDD     P   L=.35U  W=3.75U  
M17     U9_S    INCP    O2      VDD     P   L=.35U  W=1.40U  
M18     U9_S    INCPB   O2      VSS     N   L=.35U  W=1.10U  
M19     U7_S    INCPB   MFB     VDD     P   L=.35U  W=1.40U  
M20     U7_S    INCP    MFB     VSS     N   L=.35U  W=1.10U  
M21     INDB    INCP    U7_S    VDD     P   L=.35U  W=2.80U  
M22     INDB    INCPB   U7_S    VSS     N   L=.35U  W=1.80U  
M23     IND     INCPB   U9_S    VDD     P   L=.35U  W=2.60U  
M24     IND     INCP    U9_S    VSS     N   L=.35U  W=1.80U  
M25     INCP    INCPB   VSS     VSS     N   L=.35U  W=1.90U  
M26     INCP    INCPB   VDD     VDD     P   L=.35U  W=3.80U  
M27     INCPB   CP      VSS     VSS     N   L=.35U  W=1.90U  
M28     INCPB   CP      VDD     VDD     P   L=.35U  W=3.80U  
M29     INDB    D       VSS     VSS     N   L=.35U  W=1.00U  
M30     INDB    D       VDD     VDD     P   L=.35U  W=2.50U  
M31     QN      O2      VSS     VSS     N   L=.35U  W=3.00U  
M32     QN      O2      VDD     VDD     P   L=.35U  W=6.00U  
M33     Q       O1      VSS     VSS     N   L=.35U  W=3.00U  
M34     Q       O1      VDD     VDD     P   L=.35U  W=6.00U  

.ENDS DFCSN1

LPEのCDL

LPEでは、結果を準SPICEフォーマット CDL（Cadence Design Langage）で出力する。

$X,$Yで素子の座標を示している。（'$'以降はコメント扱い）
C,R等の継続行が、'+'でなく'*'で始まるコメント扱いの仕様になっている。²
'.'で始まる行だけでなく、'*.'で始まる行もコマンド行になる。

*
*  CADENCE/LPE SPICE FILE : SPICE   
*                 DATE : 29-NOV-00
*
******
******   RESISTORS   PARAMETERS FROM : 7RESXREF
******
*
*
*.GLOBAL   VDD  VSS  
*
        ：
        ：

C1  N1N29_29  N1N28_30  PLC  1.01250E-12  $X=20.50  $Y=243.50
*
        ：

R302    VSS  VSS_2  SC  1.09000E-01  $W=1.10U  $L=1.10U  $X=15.95  $Y=18.45
R336    N1N28_4  N1N28_18  SC  1.09000E-01  $W=1.10U  $L=1.10U  $X=16.25
*         $Y=205.25
        ：

M58  VSS2_84  VSS2_54  VSS_13  VSS_4  NMOST  L=0.80U  W=10.00U  AD=23.00P
+         PD=14.60U  AS=23.00P  PS=14.60U  $X=-184.50    $Y=204.80
        ：

¹当初はネット名に数字しか使えなかったが、現在では、自由に指定できるようになっている。
²プログラム作成上から言うと通常の'+'による継続の方が良いので、変な仕様である。

[top]

リファレンス

デバイス

記述例

        ダイオード:     Dxxxxx n+ n- model [ IC=vinit ]
        MOS:            Mxxxxx d g s b  model  L=value W=value
        +               [AD=area AS=area PD=len PS=len]
        +               [IC=VDS,VGS,VBS]
        抵抗:           Rxxxxx n1 n2 value
        容量:           Cxxxxx n+ n- value [ IC=vinit ]
        コイル:         Lxxxxx n+ n- value [ IC=iinit ]

        サブサーキット: Xxxxxx n1 n2 ... subckt_name

SUBCKT

回路に名前を付け、モジュール化して記述出来る。

        .SUBCKT subckt_name n1 n2 ..
            :
            :
        .ENDS subckt_name

電源

独立電源

        Vxxxx n+ n-
        + [ DC value ]
        + [ AC acmug acphase ]

        Ixxxx n+ n-
        + [ DC value ]
        + [ AC acmug acphase ]

パルス

        Vxxxx n+ n- PULSE ( vinit vpulse tdelay trise tfall tpulse tper) 

Ex.     VIN VIN 0 PULSE ( 0 5.0 20NS 5NS 5NS 25NS 60NS )

SIN

        Vxxxx n+ n- SIN ( voffset va freq tdelay theta) 

Ex.     VIN VIN 0 SIN( 0 1.0 100MEG 1NS 1E10)

折れ線近似

        Vxxxx n+ n- PWL ( t1 v1 t2 v2 t3 v3 ...) 

Ex.     VIN VIN 0 PWL( 0NS 0V 5NS 5V 10NS 0V)

解析方法

.TRAN

過渡解析、任意の波形に対する回路応答を求める。

最も一般的なシュミレーションを行なうモード。

        .TRAN tstep tstop [tstart [tmax]] [UIC]

        .TRAN   1NS 100NS

UIC指定で、各エレメントのIC=で指定されたパラメータを使用する。

.DC

静的な電圧に対する出力値、いわゆる静特性を求める。

        .DC vname vstart vstop vstep
        + [vname2 vstart2 vstop2 vstep2]

Ex.     .DC VIN 0.25 5.0 0.25
        .DC VDS 0 10 0.5 VGS 0 2 4

スイープ

以下のように、パラメータ振って解析を行なうことを示す。

Ex.     .DC VIN 0.25 5.0 0.25
        .DC VDS 0 10 0.5 VGS 0 5 1

SWEEP指定で、2次スイープのパラメータと変動オプションの指定が可能。

DEC → デケード変動
OCT → オクターブ変動
LIN → リニア変動
POI → ポイントリスト（start,stop,stepの代わりに使用することも可）

Ex.     .DC TEMP POI 4 0 30 50 100              →4点、0°,30°,50°,100°
        .TRAN 2NS 100NS SWEEP TEMP 25 75 25
        .DC xval 1k 10k .5k SWEEP TEMP LIN 5 25 125
        .DC DATA=dataname SWEEP para1 DEC 10 1K 100K

コントロール記述

.TEMP

シュミレーションの温度設定を行なう。複数指定で、温度を変え繰り返しシュミレーションする。

        .TEMP t1 [t2 .. tn]

.OPTION

主に、出力に関するオプション。

        .OPTION INGOLD=2 CSDF=2 POST

INGOLD
CSDF → hsplot用出力の指定
POST → AvanWave用出力の指定

.LIB

ライブラリ内の指定したラベルの付いたモデルを読み込む。³

        .LIB    '/home/libdata/hspice/para2/b500h.0.2.typ.par' TT

.INCLUDE

指定したファイルを読み込む。

        .INCLUDE        '/home/libdata/hspice/para2/b500h.bjt.0.0.par'

³複数のモデルパラメータを1つのファイルに出来る。tsmcライブラリ等はこの形式。

[top] [Homeに戻る]